• 首页
• 产品目录
  • 加密产品
    • 标准版
    • 标准版+
    • 专业版
  • 商用安全产品
    • 数据服务器
    • 安全U盘
    • Web 防篡改系统
  • 企业防泄密系统
    • 设计经典版
    • 管理平台版
    • 至尊企业版
• 解决方案
• 服务与支持
  • 在线支持
  • 软件下载
• 保密技术
• 关于我们

　　在已经安装了secWall企业版并且加密用户已经正常登录的机器中，将repair.bat文件放到电脑中某一位置，比如C盘根目录。

　　打开“开始菜单”→“所有程序”→“命令提示符”，右键选择“以管理员身份运行”。

　　进入到command界面后，进入repair.bat所在位置。之前将文件存放在了C盘根目录，输入“cd\”回车后进入C盘根目录，如下图所示。

　　之后就可以执行修复命令了，命令格式为“repair.bat <源文件夹> <目标文件夹>”，如下图所示。

　　输入命令“repair.bat d:\损坏的文件 d:\修复的文件”，源文件夹中存放的是需要修复的文件，修复成功或者不需要修复的文件会自动复制到目标文件夹。

　　如果目标文件夹不存在，会自动在指定位置创建。

　　注：批处理中假设secWall是安装在默认位置中的，如果用户在安装时修改了默认的安装目录，应该修改批处理文件中MWDocMan.com的位置

　　如果文件中有未正确修复的文件，会在repair.bat的存放路径下生成一个名为repair.log的日志文件，其中记录了未正确修复的文件信息。

　　程序执行完毕后，在目标文件夹中的文件即是所有修复成功并且可以正常使用的加密文件。

repair.bat代码：

　　将以下这段代码保存到记事本中，另存为repair.bat文件

　　　　@echo off

　　　　REM 用法：repair <源文件夹> <目标文件夹>

　　　　if "%1" equ "" goto _usage
　　　　if "%2" equ "" goto _usage
　　　　if not exist %1 goto _usage
　　　　if not exist %2 md %2
　　　　if not exist %2 goto _usage

　　　　REM 初始化Log文件
　　　　if exist repair.log (
　　　　　 move repair.log repair.bak > NUL
　　　　)

　　　　for /r %1 %%i in (*.*) do call :fix "%%i" %1 %2
　　　　goto _end

　　　　REM 参数1：源文件
　　　　REM 参数2：源文件夹
　　　　REM 参数3：目标文件夹
　　　　:fix
　　　　REM SetLocal ENABLEDELAYEDEXPANSION
　　　　set srcfile=%~1
　　　　set destfile=%srcfile%
　　　　call set "destfile=%%destfile:%2=%3%%"
　　　　call :_getpathname "%destfile%"
　　　　if not exist "%getpathname%" md "%getpathname%"
　　　　echo %srcfile%
　　　　"%ProgramFiles%\Mawadata secWall\MWDocMan.com" -repair -i "%srcfile%" -o "%destfile%"
　　　　set errorcode=%errorlevel%
　　　　if %errorcode% equ -2147483636 (
　　　　REM 正常的文件不会被修复，把正常的文件直接复制到目标文件夹
　　　　　copy "%srcfile%" "%destfile%"
　　　　) else if %errorcode% neq 0 (
　　　　REM 未正确修复的文件记录到Log文件
　　　　　call echo "%srcfile%", %errorcode% >> repair.log
　　　　)
　　　　REM EndLocal
　　　　goto _end

　　　　:_getpathname
　　　　set getpathname=%~dp1
　　　　goto _end

　　　　:_usage
　　　　echo 批量修复丢失加密信息的加密文件
　　　　echo.
　　　　echo Usage:
　　　　echo.
　　　　echo  repair source_folder target_folder
　　　　echo.
　　　　echo source_folder: 存放损坏加密文件的文件夹
　　　　echo target_folder: 保存修复的文件的文件夹
　　　　echo.

　　　　:_end

下载链接：repair.bat